Contract Source Code:
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
* @dev Contract module which provides a basic access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership}.
*
* This module is used through inheritance. It will make available the modifier
* `onlyOwner`, which can be applied to your functions to restrict their use to
* the owner.
*/
abstract contract Ownable is Context {
address private _owner;
event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
/**
* @dev Initializes the contract setting the deployer as the initial owner.
*/
constructor() {
_transferOwnership(_msgSender());
}
/**
* @dev Throws if called by any account other than the owner.
*/
modifier onlyOwner() {
_checkOwner();
_;
}
/**
* @dev Returns the address of the current owner.
*/
function owner() public view virtual returns (address) {
return _owner;
}
/**
* @dev Throws if the sender is not the owner.
*/
function _checkOwner() internal view virtual {
require(owner() == _msgSender(), "Ownable: caller is not the owner");
}
/**
* @dev Leaves the contract without owner. It will not be possible to call
* `onlyOwner` functions. Can only be called by the current owner.
*
* NOTE: Renouncing ownership will leave the contract without an owner,
* thereby disabling any functionality that is only available to the owner.
*/
function renounceOwnership() public virtual onlyOwner {
_transferOwnership(address(0));
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual onlyOwner {
require(newOwner != address(0), "Ownable: new owner is the zero address");
_transferOwnership(newOwner);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Internal function without access restriction.
*/
function _transferOwnership(address newOwner) internal virtual {
address oldOwner = _owner;
_owner = newOwner;
emit OwnershipTransferred(oldOwner, newOwner);
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable2Step.sol)
pragma solidity ^0.8.0;
import "./Ownable.sol";
/**
* @dev Contract module which provides access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership} and {acceptOwnership}.
*
* This module is used through inheritance. It will make available all functions
* from parent (Ownable).
*/
abstract contract Ownable2Step is Ownable {
address private _pendingOwner;
event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);
/**
* @dev Returns the address of the pending owner.
*/
function pendingOwner() public view virtual returns (address) {
return _pendingOwner;
}
/**
* @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual override onlyOwner {
_pendingOwner = newOwner;
emit OwnershipTransferStarted(owner(), newOwner);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
* Internal function without access restriction.
*/
function _transferOwnership(address newOwner) internal virtual override {
delete _pendingOwner;
super._transferOwnership(newOwner);
}
/**
* @dev The new owner accepts the ownership transfer.
*/
function acceptOwnership() public virtual {
address sender = _msgSender();
require(pendingOwner() == sender, "Ownable2Step: caller is not the new owner");
_transferOwnership(sender);
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)
pragma solidity ^0.8.0;
/**
* @dev Contract module that helps prevent reentrant calls to a function.
*
* Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
* available, which can be applied to functions to make sure there are no nested
* (reentrant) calls to them.
*
* Note that because there is a single `nonReentrant` guard, functions marked as
* `nonReentrant` may not call one another. This can be worked around by making
* those functions `private`, and then adding `external` `nonReentrant` entry
* points to them.
*
* TIP: If you would like to learn more about reentrancy and alternative ways
* to protect against it, check out our blog post
* https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
*/
abstract contract ReentrancyGuard {
// Booleans are more expensive than uint256 or any type that takes up a full
// word because each write operation emits an extra SLOAD to first read the
// slot's contents, replace the bits taken up by the boolean, and then write
// back. This is the compiler's defense against contract upgrades and
// pointer aliasing, and it cannot be disabled.
// The values being non-zero value makes deployment a bit more expensive,
// but in exchange the refund on every call to nonReentrant will be lower in
// amount. Since refunds are capped to a percentage of the total
// transaction's gas, it is best to keep them low in cases like this one, to
// increase the likelihood of the full refund coming into effect.
uint256 private constant _NOT_ENTERED = 1;
uint256 private constant _ENTERED = 2;
uint256 private _status;
constructor() {
_status = _NOT_ENTERED;
}
/**
* @dev Prevents a contract from calling itself, directly or indirectly.
* Calling a `nonReentrant` function from another `nonReentrant`
* function is not supported. It is possible to prevent this from happening
* by making the `nonReentrant` function external, and making it call a
* `private` function that does the actual work.
*/
modifier nonReentrant() {
_nonReentrantBefore();
_;
_nonReentrantAfter();
}
function _nonReentrantBefore() private {
// On the first call to nonReentrant, _status will be _NOT_ENTERED
require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
// Any calls to nonReentrant after this point will fail
_status = _ENTERED;
}
function _nonReentrantAfter() private {
// By storing the original value once again, a refund is triggered (see
// https://eips.ethereum.org/EIPS/eip-2200)
_status = _NOT_ENTERED;
}
/**
* @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
* `nonReentrant` function in the call stack.
*/
function _reentrancyGuardEntered() internal view returns (bool) {
return _status == _ENTERED;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
* https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
*
* Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
* presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
* need to send a transaction, and thus is not required to hold Ether at all.
*
* ==== Security Considerations
*
* There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
* expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
* considered as an intention to spend the allowance in any specific way. The second is that because permits have
* built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
* take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
* generally recommended is:
*
* ```solidity
* function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
* try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
* doThing(..., value);
* }
*
* function doThing(..., uint256 value) public {
* token.safeTransferFrom(msg.sender, address(this), value);
* ...
* }
* ```
*
* Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
* `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
* {SafeERC20-safeTransferFrom}).
*
* Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
* contracts should have entry points that don't rely on permit.
*/
interface IERC20Permit {
/**
* @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
* given ``owner``'s signed approval.
*
* IMPORTANT: The same issues {IERC20-approve} has related to transaction
* ordering also apply here.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `deadline` must be a timestamp in the future.
* - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
* over the EIP712-formatted function arguments.
* - the signature must use ``owner``'s current nonce (see {nonces}).
*
* For more information on the signature format, see the
* https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
* section].
*
* CAUTION: See Security Considerations above.
*/
function permit(
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external;
/**
* @dev Returns the current nonce for `owner`. This value must be
* included whenever a signature is generated for {permit}.
*
* Every successful call to {permit} increases ``owner``'s nonce by one. This
* prevents a signature from being used multiple times.
*/
function nonces(address owner) external view returns (uint256);
/**
* @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
*/
// solhint-disable-next-line func-name-mixedcase
function DOMAIN_SEPARATOR() external view returns (bytes32);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
/**
* @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeTransfer(IERC20 token, address to, uint256 value) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
}
/**
* @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
* calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
*/
function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
}
/**
* @dev Deprecated. This function has issues similar to the ones found in
* {IERC20-approve}, and its usage is discouraged.
*
* Whenever possible, use {safeIncreaseAllowance} and
* {safeDecreaseAllowance} instead.
*/
function safeApprove(IERC20 token, address spender, uint256 value) internal {
// safeApprove should only be called when setting an initial allowance,
// or when resetting it to zero. To increase and decrease it, use
// 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
require(
(value == 0) || (token.allowance(address(this), spender) == 0),
"SafeERC20: approve from non-zero to non-zero allowance"
);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
}
/**
* @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
uint256 oldAllowance = token.allowance(address(this), spender);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
}
/**
* @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
unchecked {
uint256 oldAllowance = token.allowance(address(this), spender);
require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
}
}
/**
* @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
* to be set to zero before setting it to a non-zero value, such as USDT.
*/
function forceApprove(IERC20 token, address spender, uint256 value) internal {
bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);
if (!_callOptionalReturnBool(token, approvalCall)) {
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
_callOptionalReturn(token, approvalCall);
}
}
/**
* @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
* Revert on invalid signature.
*/
function safePermit(
IERC20Permit token,
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) internal {
uint256 nonceBefore = token.nonces(owner);
token.permit(owner, spender, value, deadline, v, r, s);
uint256 nonceAfter = token.nonces(owner);
require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*
* This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
*/
function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
// and not revert is the subcall reverts.
(bool success, bytes memory returndata) = address(token).call(data);
return
success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
*
* Furthermore, `isContract` will also return true if the target contract within
* the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
* which only has an effect at the end of a transaction.
* ====
*
* [IMPORTANT]
* ====
* You shouldn't rely on `isContract` to protect against flash loan attacks!
*
* Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
* like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
* constructor.
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize/address.code.length, which returns 0
// for contracts in construction, since the code is only stored at the end
// of the constructor execution.
return account.code.length > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(address(this).balance >= amount, "Address: insufficient balance");
(bool success, ) = recipient.call{value: amount}("");
require(success, "Address: unable to send value, recipient may have reverted");
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(address(this).balance >= value, "Address: insufficient balance for call");
(bool success, bytes memory returndata) = target.call{value: value}(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
return functionStaticCall(target, data, "Address: low-level static call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
(bool success, bytes memory returndata) = target.staticcall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
return functionDelegateCall(target, data, "Address: low-level delegate call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
(bool success, bytes memory returndata) = target.delegatecall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
* the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
*
* _Available since v4.8._
*/
function verifyCallResultFromTarget(
address target,
bool success,
bytes memory returndata,
string memory errorMessage
) internal view returns (bytes memory) {
if (success) {
if (returndata.length == 0) {
// only check isContract if the call was successful and the return data is empty
// otherwise we already know that it was a contract
require(isContract(target), "Address: call to non-contract");
}
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
/**
* @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
* revert reason or using the provided one.
*
* _Available since v4.3._
*/
function verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) internal pure returns (bytes memory) {
if (success) {
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
function _revert(bytes memory returndata, string memory errorMessage) private pure {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
/// @solidity memory-safe-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)
pragma solidity ^0.8.0;
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
function _contextSuffixLength() internal view virtual returns (uint256) {
return 0;
}
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
library Constants {
uint48 constant EPOCH = 1 weeks;
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
import {ReentrancyGuard} from "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import {Ownable2Step} from "@openzeppelin/contracts/access/Ownable2Step.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {IPairInfo} from "./interfaces/IPairInfo.sol";
import {IBribe} from "./interfaces/IBribe.sol";
import {IFeeVault} from "./interfaces/IFeeVault.sol";
import {IRewarder} from "./interfaces/IRewarder.sol";
import {Math} from "./libraries/Math.sol";
import {Constants} from "./Constants.sol";
import {GaugeV2} from "./GaugeV2.sol";
contract GaugeV2_CL is ReentrancyGuard, Ownable2Step, GaugeV2 {
address public feeVault;
constructor(
address _rewardToken,
address _ve,
address _stakeToken,
address _distribution,
address _internal_bribe,
address _external_bribe,
address _feeVault
) GaugeV2(_rewardToken, _ve, _stakeToken, _distribution, _internal_bribe, _external_bribe, true) {
feeVault = _feeVault; // fee vault concentrated liquidity position
}
///@notice set feeVault address
function setFeeVault(address _feeVault) external onlyOwner {
require(_feeVault != address(0), "zero addr");
require(_feeVault != feeVault, "same addr");
feeVault = _feeVault;
}
function _claimFees() internal override returns (uint256 claimed0, uint256 claimed1) {
address _stakeToken = address(stakeToken);
(claimed0, claimed1) = IFeeVault(feeVault).claimFees();
if (claimed0 > 0 || claimed1 > 0) {
uint256 _fees0 = claimed0;
uint256 _fees1 = claimed1;
address _token0 = IPairInfo(_stakeToken).token0();
address _token1 = IPairInfo(_stakeToken).token1();
if (_fees0 > 0) {
IERC20(_token0).approve(internal_bribe, 0);
IERC20(_token0).approve(internal_bribe, _fees0);
IBribe(internal_bribe).notifyRewardAmount(_token0, _fees0);
}
if (_fees1 > 0) {
IERC20(_token1).approve(internal_bribe, 0);
IERC20(_token1).approve(internal_bribe, _fees1);
IBribe(internal_bribe).notifyRewardAmount(_token1, _fees1);
}
emit ClaimFees(msg.sender, claimed0, claimed1);
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
import { ReentrancyGuard } from "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import { Ownable2Step } from "@openzeppelin/contracts/access/Ownable2Step.sol";
import { SafeERC20 } from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import { IPair } from './interfaces/IPair.sol';
import { IBribe } from './interfaces/IBribe.sol';
import { IGauge } from './interfaces/IGauge.sol';
import {IRewarder} from './interfaces/IRewarder.sol';
import { Math } from "./libraries/Math.sol";
import { Constants } from "./Constants.sol";
import { IVoterV5 } from './interfaces/IVoterV5.sol';
contract GaugeV2 is ReentrancyGuard, Ownable2Step {
using SafeERC20 for IERC20;
bool public immutable isForPair;
bool public emergency;
IERC20 public rewardToken;
IERC20 public immutable stakeToken;
address public VE;
address public DISTRIBUTION;
address public gaugeRewarder;
address public internal_bribe;
address public external_bribe;
uint256 public immutable DURATION;
uint internal constant MAX_REWARD_TOKENS = 6;
address[] public rewards;
mapping(address => bool) public isReward;
mapping(address => uint) public rewardRate;
mapping(address => uint) public periodFinishToken;
mapping(address => uint) public lastUpdateTime;
mapping(address => uint) public rewardPerTokenStored;
mapping(address => mapping(address => uint)) public lastEarn;
mapping(address => mapping(address => uint)) public userRewardPerTokenStored;
mapping(address => mapping(address => uint)) public userRewardPerTokenPaid;
uint256 internal _totalSupply;
mapping(address => uint256) internal _balances;
mapping(address => uint) public balanceWithLock;
mapping(address => uint) public lockEnd;
/// @dev Events
event RewardAdded(uint256 reward);
event Deposit(address indexed user, uint256 amount);
event Withdraw(address indexed user, uint256 amount);
event Harvest(address indexed user, uint256 reward);
event ClaimFees(address indexed from, uint256 claimed0, uint256 claimed1);
event EmergencyActivated(address indexed gauge, uint256 timestamp);
event EmergencyDeactivated(address indexed gauge, uint256 timestamp);
event SetDistribution(address newDistribution);
event SetRewarder(address newRewarder);
event NotifyReward(address sender, address token, uint256 amount);
/// @dev Errors
error OnlyDistributor();
error IsEmergency(bool emergency);
error ZeroAddress();
error SameAddress();
error OnlyAllowed();
error InvalidAmount();
error NoBalances();
modifier updateReward(address account) {
_updateRewardForAllTokens(account);
_;
}
modifier onlyDistribution() {
if(msg.sender != DISTRIBUTION) revert OnlyDistributor();
_;
}
modifier isNotEmergency() {
if(emergency == true) revert IsEmergency(emergency);
_;
}
constructor(address _rewardToken,address _ve,address _token,address _distribution, address _internal_bribe, address _external_bribe, bool _isForPair) {
rewardToken = IERC20(_rewardToken); // main reward
VE = _ve; // vested
stakeToken = IERC20(_token); // underlying (LP)
DISTRIBUTION = _distribution; // distribution address (voter)
DURATION = Constants.EPOCH; // distribution time
internal_bribe = _internal_bribe; // lp fees goes here
external_bribe = _external_bribe; // bribe fees goes here
isForPair = _isForPair; // pair boolean, if false no claim_fees
emergency = false;
isReward[_rewardToken] = true;
rewards.push(_rewardToken); // emergency flag
}
/* -----------------------------------------------------------------------------
--------------------------------------------------------------------------------
--------------------------------------------------------------------------------
ONLY OWNER
--------------------------------------------------------------------------------
--------------------------------------------------------------------------------
----------------------------------------------------------------------------- */
///@notice set distribution address (should be voter)
function setDistribution(address _distribution) external onlyOwner {
if(_distribution == address(0)) revert ZeroAddress();
if(_distribution == DISTRIBUTION) revert SameAddress();
DISTRIBUTION = _distribution;
emit SetDistribution(DISTRIBUTION);
}
///@notice set gauge rewarder address
function setGaugeRewarder(address _gaugeRewarder) external onlyOwner {
if(_gaugeRewarder == gaugeRewarder) revert SameAddress();
gaugeRewarder = _gaugeRewarder;
emit SetRewarder(gaugeRewarder);
}
///@notice set new internal bribe contract (where to send fees)
function setInternalBribe(address _int) external onlyOwner {
if(_int == address(0)) revert ZeroAddress();
internal_bribe = _int;
}
function activateEmergencyMode() external onlyOwner {
if(emergency == true) revert IsEmergency(emergency);
emergency = true;
emit EmergencyActivated(address(this), block.timestamp);
}
function stopEmergencyMode() external onlyOwner {
if(emergency == false) revert IsEmergency(emergency);
emergency = false;
emit EmergencyDeactivated(address(this), block.timestamp);
}
/// @notice Update rewardToken address to match with Voter contract
function updateRewardToken() external onlyOwner {
isReward[address(rewardToken)] = false;
address rewardAddress = IVoterV5(DISTRIBUTION).oLynx();
if (rewardAddress == address(0)) {
rewardAddress = IVoterV5(DISTRIBUTION).base();
}
if (!isReward[rewardAddress]) {
isReward[rewardAddress] = true;
}
rewards.push(rewardAddress);
rewardToken = IERC20(rewardAddress);
}
/// @notice Owner can add reward tokens beyond limit
function addRewardToken(address _rewardTokn) external onlyOwner {
if (!isReward[_rewardTokn]) {
isReward[_rewardTokn] = true;
rewards.push(_rewardTokn);
} else {
revert("Already added");
}
}
/* -----------------------------------------------------------------------------
--------------------------------------------------------------------------------
--------------------------------------------------------------------------------
VIEW FUNCTIONS
--------------------------------------------------------------------------------
--------------------------------------------------------------------------------
----------------------------------------------------------------------------- */
///@notice total supply held
function totalSupply() public view returns (uint256) {
return _totalSupply;
}
///@notice balance of a user
function balanceOf(address account) external view returns (uint256) {
return _balances[account];
}
function availableBalance(address account) public view returns (uint) {
if (block.timestamp >= lockEnd[account]) return _balances[account];
return _balances[account] - balanceWithLock[account];
}
function lastTimeRewardApplicable(address rewardAddress) public view returns (uint256) {
return Math.min(block.timestamp, periodFinishToken[rewardAddress]);
}
function rewardPerToken(address rewardAddress) public view returns (uint256) {
if (_totalSupply == 0) {
return rewardPerTokenStored[rewardAddress];
} else {
return rewardPerTokenStored[rewardAddress] + (lastTimeRewardApplicable(rewardAddress) - lastUpdateTime[rewardAddress]) * rewardRate[rewardAddress] * 1e18 / _totalSupply;
}
}
///@notice see earned rewards for user
function earned(address account) external view returns (uint256) {
return earned(account, address(rewardToken));
}
///@notice see earned rewards for user
function earned(address account, address rewardAddress) public view returns (uint256) {
return userRewardPerTokenStored[rewardAddress][account] + _balances[account] * (rewardPerToken(rewardAddress) - userRewardPerTokenPaid[rewardAddress][account]) / 1e18;
}
///@notice get total reward for the duration
function rewardForDuration(address rewardAddress) public view returns (uint256) {
return rewardRate[rewardAddress] * DURATION;
}
function periodFinish(address rewardAddress) public view returns (uint256) {
return periodFinishToken[rewardAddress];
}
/* -----------------------------------------------------------------------------
--------------------------------------------------------------------------------
--------------------------------------------------------------------------------
USER INTERACTION
--------------------------------------------------------------------------------
--------------------------------------------------------------------------------
----------------------------------------------------------------------------- */
///@notice deposit all stakeToken of msg.sender
function depositAll() external {
_deposit(stakeToken.balanceOf(msg.sender), msg.sender);
}
///@notice deposit amount stakeToken
function deposit(uint256 amount) external {
_deposit(amount, msg.sender);
}
///@notice deposits a locked LP position. Generally called from oToken
function depositWithLock(address account, uint256 amount, uint256 _lockDuration) external {
require(msg.sender == account || msg.sender == address(rewardToken) || IVoterV5(DISTRIBUTION).isGaugeDepositor(msg.sender), "Not allowed to deposit with lock");
_deposit(amount, account);
if(block.timestamp >= lockEnd[account]) {
// if the current lock is expired release the tokens from that lock before locking again
delete lockEnd[account];
delete balanceWithLock[account];
}
balanceWithLock[account] += amount;
uint256 currentLockEnd = lockEnd[account];
uint256 newLockEnd = block.timestamp + _lockDuration ;
if (currentLockEnd > newLockEnd) {
// The lock end can only be extended
revert("The current lock end > new lock end");
}
lockEnd[account] = newLockEnd;
}
///@notice deposit internal
function _deposit(uint256 amount, address account) internal nonReentrant isNotEmergency updateReward(account) {
if(amount <= 0) revert InvalidAmount();
_balances[account] = _balances[account] + amount;
_totalSupply = _totalSupply + amount;
if (address(gaugeRewarder) != address(0)) {
IRewarder(gaugeRewarder).onReward(account, account, _balances[account]);
}
stakeToken.safeTransferFrom(msg.sender, address(this), amount);
emit Deposit(account, amount);
}
///@notice withdraw all token
function withdrawAll() external {
_withdraw(_balances[msg.sender]);
}
///@notice withdraw a certain amount of stakeToken
function withdraw(uint256 amount) external {
_withdraw(amount);
}
///@notice withdraw internal
function _withdraw(uint256 amount) internal nonReentrant isNotEmergency updateReward(msg.sender) {
if(amount <= 0) revert InvalidAmount();
if(_balances[msg.sender] <= 0) revert NoBalances();
if(block.timestamp >= lockEnd[msg.sender]) {
// if the current lock is expired, release the tokens
delete lockEnd[msg.sender];
delete balanceWithLock[msg.sender];
}
uint256 totalBalance = _balances[msg.sender];
uint256 lockedAmount = balanceWithLock[msg.sender];
uint256 freeAmount = totalBalance - lockedAmount;
// Update lock related mappings when withdraw amount greater than free amount
if (amount > freeAmount) {
revert("Cannot withdraw more than free amount");
}
_totalSupply -= amount;
_balances[msg.sender] -= amount;
if (address(gaugeRewarder) != address(0)) {
IRewarder(gaugeRewarder).onReward(msg.sender, msg.sender,_balances[msg.sender]);
}
stakeToken.safeTransfer(msg.sender, amount);
emit Withdraw(msg.sender, amount);
}
function emergencyWithdraw() external nonReentrant {
if(!emergency) revert IsEmergency(emergency);
if(_balances[msg.sender] <= 0) revert NoBalances();
uint256 _amount = _balances[msg.sender];
_totalSupply = _totalSupply - _amount;
_balances[msg.sender] = 0;
if (gaugeRewarder != address(0)) {
IRewarder(gaugeRewarder).onEmergencyWithdrawAmount(msg.sender, _amount);
}
stakeToken.safeTransfer(msg.sender, _amount);
emit Withdraw(msg.sender, _amount);
}
function emergencyWithdrawAmount(uint256 _amount) external nonReentrant {
if(!emergency) revert IsEmergency(emergency);
if(_balances[msg.sender] < _amount) revert NoBalances();
_totalSupply = _totalSupply - _amount;
_balances[msg.sender] -= _amount;
if (gaugeRewarder != address(0)) {
IRewarder(gaugeRewarder).onEmergencyWithdrawAmount(msg.sender, _amount);
}
stakeToken.safeTransfer(msg.sender, _amount);
emit Withdraw(msg.sender, _amount);
}
///@notice withdraw all stakeToken and harvest rewardToken
function withdrawAllAndHarvest() external {
_withdraw(_balances[msg.sender]);
getReward();
}
/// @notice User harvest function called from distribution (voter allows harvest on multiple gauges)
function getReward(address _user) external onlyDistribution {
address[] memory tokens = new address[](1);
tokens[0] = address(rewardToken);
return _getReward(_user, tokens);
}
/// @notice User harvest function
/// Enables backward compatibility and focuses on harvesting main reward tokern
function getReward() public {
address[] memory tokens = new address[](1);
tokens[0] = address(rewardToken);
return _getReward(msg.sender, tokens);
}
///@notice User harvest function called from distribution (voter allows harvest on multiple gauges)
function getReward(address _user, address[] memory tokens) external {
require(msg.sender == _user || msg.sender == DISTRIBUTION);
return _getReward(_user, tokens);
}
function _getReward(address _user, address[] memory tokens) internal nonReentrant updateReward(_user) {
uint length = tokens.length;
for (uint i = 0; i < length; i++) {
address rewardAddress = tokens[i];
uint256 reward = userRewardPerTokenStored[rewardAddress][_user];
if (reward > 0) {
userRewardPerTokenStored[rewardAddress][_user] = 0;
IERC20(rewardAddress).safeTransfer(_user, reward);
emit Harvest(_user, reward);
}
}
if (gaugeRewarder != address(0)) {
IRewarder(gaugeRewarder).onReward(_user, _user, _balances[_user]);
}
}
function left(address token) external view returns (uint) {
if (block.timestamp >= periodFinishToken[token]) return 0;
uint _remaining = periodFinishToken[token] - block.timestamp;
return _remaining * rewardRate[token];
}
function _updateRewardForAllTokens(address account) internal {
uint256 length = rewards.length;
for (uint i; i < length; i++) {
address rewardAddress = rewards[i];
rewardPerTokenStored[rewardAddress] = rewardPerToken(rewardAddress);
lastUpdateTime[rewardAddress] = lastTimeRewardApplicable(rewardAddress);
if (account != address(0)) {
userRewardPerTokenStored[rewardAddress][account] = earned(account, rewardAddress);
userRewardPerTokenPaid[rewardAddress][account] = rewardPerTokenStored[rewardAddress];
}
}
}
/* -----------------------------------------------------------------------------
--------------------------------------------------------------------------------
--------------------------------------------------------------------------------
DISTRIBUTION
--------------------------------------------------------------------------------
--------------------------------------------------------------------------------
----------------------------------------------------------------------------- */
/// @dev Receive rewards
function notifyRewardAmount(address rewardAddress, uint256 rewardAmount) external virtual nonReentrant isNotEmergency updateReward(address(0)) {
uint256 balanceBefore = IERC20(rewardAddress).balanceOf(address(this));
IERC20(rewardAddress).safeTransferFrom(msg.sender, address(this), rewardAmount);
uint256 balanceAfter = IERC20(rewardAddress).balanceOf(address(this));
rewardAmount = balanceAfter - balanceBefore;
_notifyRewardAmount(rewardAddress, rewardAmount);
}
function _notifyRewardAmount(address rewardAddress, uint rewardAmount) internal {
require(rewardAddress != address(stakeToken), "Can't add stake token as reward");
require(rewardAmount > 0, "Reward amount needs to be higher than 0");
if (!isReward[rewardAddress]) {
require(IVoterV5(DISTRIBUTION).isWhitelisted(rewardAddress), "rewards tokens must be whitelisted");
if (rewardAddress != IVoterV5(DISTRIBUTION).oLynx() && rewardAddress != IVoterV5(DISTRIBUTION).base())
require(rewards.length < MAX_REWARD_TOKENS, "too many rewards tokens");
}
if (block.timestamp >= periodFinishToken[rewardAddress]) {
rewardRate[rewardAddress] = rewardAmount / DURATION;
} else {
uint256 remaining = periodFinishToken[rewardAddress] - block.timestamp;
uint256 leftover = remaining * rewardRate[rewardAddress];
/// @dev: This will spread the remaining rewards over the new period.
rewardRate[rewardAddress] = (rewardAmount + leftover) / DURATION;
}
// Ensure the provided reward amount is not more than the balance in the contract.
// This keeps the reward rate in the right range, preventing overflows due to
// very high values of rewardRate in the earned and rewardsPerToken functions;
// Reward + leftover must be less than 2^256 / 10^18 to avoid overflow.
uint256 balance = IERC20(rewardAddress).balanceOf(address(this));
require(rewardRate[rewardAddress] <= balance / DURATION, "Provided reward too high");
lastUpdateTime[rewardAddress] = block.timestamp;
periodFinishToken[rewardAddress] = block.timestamp + DURATION;
if (!isReward[rewardAddress]) {
isReward[rewardAddress] = true;
rewards.push(rewardAddress);
}
emit NotifyReward(msg.sender, rewardAddress, rewardAmount);
}
function claimFees() external nonReentrant returns (uint256 claimed0, uint256 claimed1) {
return _claimFees();
}
function _claimFees() internal virtual returns (uint256 claimed0, uint256 claimed1) {
if (!isForPair) {
return (0, 0);
}
address _token = address(stakeToken);
(claimed0, claimed1) = IPair(_token).claimFees();
if (claimed0 > 0 || claimed1 > 0) {
uint256 _fees0 = claimed0;
uint256 _fees1 = claimed1;
(address _token0, address _token1) = IPair(_token).tokens();
if (_fees0 > 0) {
IERC20(_token0).approve(internal_bribe, 0);
IERC20(_token0).approve(internal_bribe, _fees0);
IBribe(internal_bribe).notifyRewardAmount(_token0, _fees0);
}
if (_fees1 > 0) {
IERC20(_token1).approve(internal_bribe, 0);
IERC20(_token1).approve(internal_bribe, _fees1);
IBribe(internal_bribe).notifyRewardAmount(_token1, _fees1);
}
emit ClaimFees(msg.sender, claimed0, claimed1);
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
interface IBribe {
function deposit(uint amount, uint tokenId) external;
function withdraw(uint amount, uint tokenId) external;
function getRewardForOwner(uint tokenId, address[] memory tokens) external;
function getRewardForAddress(address _owner, address[] memory tokens) external;
function notifyRewardAmount(address token, uint amount) external;
function addReward(address) external;
function setVoter(address _Voter) external;
function setMinter(address _Voter) external;
function setOwner(address _Voter) external;
function emergencyRecoverERC20(address tokenAddress, uint256 tokenAmount) external;
function recoverERC20AndUpdateData(address tokenAddress, uint256 tokenAmount) external;
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
interface IFeeVault {
function claimFees() external returns(uint256 claimed0, uint256 claimed1);
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
interface IGauge {
function notifyRewardAmount(address token, uint amount) external;
function getReward(address account, address[] memory tokens) external;
function getReward(address account) external;
function claimFees() external returns (uint claimed0, uint claimed1);
function rewardRate(address _pair) external view returns (uint);
function balanceOf(address _account) external view returns (uint);
function isForPair() external view returns (bool);
function totalSupply() external view returns (uint);
function earned(address token, address account) external view returns (uint);
function stakeToken() external view returns (address);
function setDistribution(address _distro) external;
function addRewardToken(address _rewardToken) external;
function updateRewardToken() external;
function activateEmergencyMode() external;
function stopEmergencyMode() external;
function setInternalBribe(address intbribe) external;
function setGaugeRewarder(address _gr) external;
function setFeeVault(address _feeVault) external;
function depositWithLock(address account, uint256 amount, uint256 _lockDuration) external;
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
interface IPair {
function metadata() external view returns (uint dec0, uint dec1, uint r0, uint r1, bool st, address t0, address t1);
function claimFees() external returns (uint, uint);
function tokens() external view returns (address, address);
function token0() external view returns (address);
function token1() external view returns (address);
function transferFrom(address src, address dst, uint amount) external returns (bool);
function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;
function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;
function burn(address to) external returns (uint amount0, uint amount1);
function mint(address to) external returns (uint liquidity);
function getReserves() external view returns (uint _reserve0, uint _reserve1, uint _blockTimestampLast);
function getAmountOut(uint, address) external view returns (uint);
function name() external view returns(string memory);
function symbol() external view returns(string memory);
function totalSupply() external view returns (uint);
function decimals() external view returns (uint8);
function claimable0(address _user) external view returns (uint);
function claimable1(address _user) external view returns (uint);
function isStable() external view returns(bool);
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
interface IPairInfo {
function token0() external view returns(address);
function reserve0() external view returns(uint);
function decimals0() external view returns(uint);
function token1() external view returns(address);
function reserve1() external view returns(uint);
function decimals1() external view returns(uint);
function isPair(address _pair) external view returns(bool);
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
interface IRewarder {
function onReward(uint256 pid, address user, address recipient, uint256 lqdrAmount, uint256 newLpAmount) external;
function pendingTokens(uint256 pid, address user, uint256 lqdrAmount) external view returns (IERC20[] memory, uint256[] memory);
function onReward(address user, address recipient, uint256 userBalance) external;
function onEmergencyWithdrawAmount(address user, uint256 amount) external;
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
interface IVoterV5 {
function ve() external view returns (address);
function oLynx() external view returns (address);
function base() external view returns (address);
function gauges(address _pair) external view returns (address);
function isGauge(address _gauge) external view returns (bool);
function poolForGauge(address _gauge) external view returns (address);
function factory() external view returns (address);
function minter() external view returns(address);
function isWhitelisted(address token) external view returns (bool);
function isGaugeDepositor(address depositor) external view returns (bool);
function notifyRewardAmount(uint amount) external;
function distributeAll() external;
function distributeFees(address[] memory _gauges) external;
function internal_bribes(address _gauge) external view returns (address);
function external_bribes(address _gauge) external view returns (address);
function usedWeights(address _account) external view returns(uint);
function lastVoted(address _account) external view returns(uint);
function poolVote(address _account, uint _index) external view returns(address _pair);
function votes(address _account, address _pool) external view returns(uint votes);
function poolVoteLength(address _account) external view returns(uint);
function _epochTimestamp() external view returns(uint);
}
// SPDX-License-Identifier: MIT
pragma solidity 0.8.13;
library Math {
function max(uint a, uint b) internal pure returns (uint) {
return a >= b ? a : b;
}
function min(uint a, uint b) internal pure returns (uint) {
return a < b ? a : b;
}
function sqrt(uint y) internal pure returns (uint z) {
if (y > 3) {
z = y;
uint x = y / 2 + 1;
while (x < z) {
z = x;
x = (y / x + x) / 2;
}
} else if (y != 0) {
z = 1;
}
}
function cbrt(uint256 n) internal pure returns (uint256) { unchecked {
uint256 x = 0;
for (uint256 y = 1 << 255; y > 0; y >>= 3) {
x <<= 1;
uint256 z = 3 * x * (x + 1) + 1;
if (n / y >= z) {
n -= y * z;
x += 1;
}
}
return x;
}}
function sub(uint x, uint y) internal pure returns (uint z) {
require((z = x - y) <= x, 'Math: Sub-underflow');
}
function abs(int256 n) internal pure returns (uint256) {
unchecked {
// must be unchecked in order to support `n = type(int256).min`
return uint256(n >= 0 ? n : -n);
}
}
}