Contract Name:
PolymerAdapter
Contract Source Code:
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/AccessControl.sol)
pragma solidity ^0.8.0;
import "./IAccessControl.sol";
import "../utils/Context.sol";
import "../utils/Strings.sol";
import "../utils/introspection/ERC165.sol";
/**
* @dev Contract module that allows children to implement role-based access
* control mechanisms. This is a lightweight version that doesn't allow enumerating role
* members except through off-chain means by accessing the contract event logs. Some
* applications may benefit from on-chain enumerability, for those cases see
* {AccessControlEnumerable}.
*
* Roles are referred to by their `bytes32` identifier. These should be exposed
* in the external API and be unique. The best way to achieve this is by
* using `public constant` hash digests:
*
* ```solidity
* bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
* ```
*
* Roles can be used to represent a set of permissions. To restrict access to a
* function call, use {hasRole}:
*
* ```solidity
* function foo() public {
* require(hasRole(MY_ROLE, msg.sender));
* ...
* }
* ```
*
* Roles can be granted and revoked dynamically via the {grantRole} and
* {revokeRole} functions. Each role has an associated admin role, and only
* accounts that have a role's admin role can call {grantRole} and {revokeRole}.
*
* By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
* that only accounts with this role will be able to grant or revoke other
* roles. More complex role relationships can be created by using
* {_setRoleAdmin}.
*
* WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
* grant and revoke this role. Extra precautions should be taken to secure
* accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
* to enforce additional security measures for this role.
*/
abstract contract AccessControl is Context, IAccessControl, ERC165 {
struct RoleData {
mapping(address => bool) members;
bytes32 adminRole;
}
mapping(bytes32 => RoleData) private _roles;
bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;
/**
* @dev Modifier that checks that an account has a specific role. Reverts
* with a standardized message including the required role.
*
* The format of the revert reason is given by the following regular expression:
*
* /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
*
* _Available since v4.1._
*/
modifier onlyRole(bytes32 role) {
_checkRole(role);
_;
}
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
}
/**
* @dev Returns `true` if `account` has been granted `role`.
*/
function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
return _roles[role].members[account];
}
/**
* @dev Revert with a standard message if `_msgSender()` is missing `role`.
* Overriding this function changes the behavior of the {onlyRole} modifier.
*
* Format of the revert message is described in {_checkRole}.
*
* _Available since v4.6._
*/
function _checkRole(bytes32 role) internal view virtual {
_checkRole(role, _msgSender());
}
/**
* @dev Revert with a standard message if `account` is missing `role`.
*
* The format of the revert reason is given by the following regular expression:
*
* /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
*/
function _checkRole(bytes32 role, address account) internal view virtual {
if (!hasRole(role, account)) {
revert(
string(
abi.encodePacked(
"AccessControl: account ",
Strings.toHexString(account),
" is missing role ",
Strings.toHexString(uint256(role), 32)
)
)
);
}
}
/**
* @dev Returns the admin role that controls `role`. See {grantRole} and
* {revokeRole}.
*
* To change a role's admin, use {_setRoleAdmin}.
*/
function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
return _roles[role].adminRole;
}
/**
* @dev Grants `role` to `account`.
*
* If `account` had not been already granted `role`, emits a {RoleGranted}
* event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*
* May emit a {RoleGranted} event.
*/
function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
_grantRole(role, account);
}
/**
* @dev Revokes `role` from `account`.
*
* If `account` had been granted `role`, emits a {RoleRevoked} event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*
* May emit a {RoleRevoked} event.
*/
function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
_revokeRole(role, account);
}
/**
* @dev Revokes `role` from the calling account.
*
* Roles are often managed via {grantRole} and {revokeRole}: this function's
* purpose is to provide a mechanism for accounts to lose their privileges
* if they are compromised (such as when a trusted device is misplaced).
*
* If the calling account had been revoked `role`, emits a {RoleRevoked}
* event.
*
* Requirements:
*
* - the caller must be `account`.
*
* May emit a {RoleRevoked} event.
*/
function renounceRole(bytes32 role, address account) public virtual override {
require(account == _msgSender(), "AccessControl: can only renounce roles for self");
_revokeRole(role, account);
}
/**
* @dev Grants `role` to `account`.
*
* If `account` had not been already granted `role`, emits a {RoleGranted}
* event. Note that unlike {grantRole}, this function doesn't perform any
* checks on the calling account.
*
* May emit a {RoleGranted} event.
*
* [WARNING]
* ====
* This function should only be called from the constructor when setting
* up the initial roles for the system.
*
* Using this function in any other way is effectively circumventing the admin
* system imposed by {AccessControl}.
* ====
*
* NOTE: This function is deprecated in favor of {_grantRole}.
*/
function _setupRole(bytes32 role, address account) internal virtual {
_grantRole(role, account);
}
/**
* @dev Sets `adminRole` as ``role``'s admin role.
*
* Emits a {RoleAdminChanged} event.
*/
function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
bytes32 previousAdminRole = getRoleAdmin(role);
_roles[role].adminRole = adminRole;
emit RoleAdminChanged(role, previousAdminRole, adminRole);
}
/**
* @dev Grants `role` to `account`.
*
* Internal function without access restriction.
*
* May emit a {RoleGranted} event.
*/
function _grantRole(bytes32 role, address account) internal virtual {
if (!hasRole(role, account)) {
_roles[role].members[account] = true;
emit RoleGranted(role, account, _msgSender());
}
}
/**
* @dev Revokes `role` from `account`.
*
* Internal function without access restriction.
*
* May emit a {RoleRevoked} event.
*/
function _revokeRole(bytes32 role, address account) internal virtual {
if (hasRole(role, account)) {
_roles[role].members[account] = false;
emit RoleRevoked(role, account, _msgSender());
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)
pragma solidity ^0.8.0;
/**
* @dev External interface of AccessControl declared to support ERC165 detection.
*/
interface IAccessControl {
/**
* @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
*
* `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
* {RoleAdminChanged} not being emitted signaling this.
*
* _Available since v3.1._
*/
event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);
/**
* @dev Emitted when `account` is granted `role`.
*
* `sender` is the account that originated the contract call, an admin role
* bearer except when using {AccessControl-_setupRole}.
*/
event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);
/**
* @dev Emitted when `account` is revoked `role`.
*
* `sender` is the account that originated the contract call:
* - if using `revokeRole`, it is the admin role bearer
* - if using `renounceRole`, it is the role bearer (i.e. `account`)
*/
event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);
/**
* @dev Returns `true` if `account` has been granted `role`.
*/
function hasRole(bytes32 role, address account) external view returns (bool);
/**
* @dev Returns the admin role that controls `role`. See {grantRole} and
* {revokeRole}.
*
* To change a role's admin, use {AccessControl-_setRoleAdmin}.
*/
function getRoleAdmin(bytes32 role) external view returns (bytes32);
/**
* @dev Grants `role` to `account`.
*
* If `account` had not been already granted `role`, emits a {RoleGranted}
* event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*/
function grantRole(bytes32 role, address account) external;
/**
* @dev Revokes `role` from `account`.
*
* If `account` had been granted `role`, emits a {RoleRevoked} event.
*
* Requirements:
*
* - the caller must have ``role``'s admin role.
*/
function revokeRole(bytes32 role, address account) external;
/**
* @dev Revokes `role` from the calling account.
*
* Roles are often managed via {grantRole} and {revokeRole}: this function's
* purpose is to provide a mechanism for accounts to lose their privileges
* if they are compromised (such as when a trusted device is misplaced).
*
* If the calling account had been granted `role`, emits a {RoleRevoked}
* event.
*
* Requirements:
*
* - the caller must be `account`.
*/
function renounceRole(bytes32 role, address account) external;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
* @dev Contract module which allows children to implement an emergency stop
* mechanism that can be triggered by an authorized account.
*
* This module is used through inheritance. It will make available the
* modifiers `whenNotPaused` and `whenPaused`, which can be applied to
* the functions of your contract. Note that they will not be pausable by
* simply including this module, only once the modifiers are put in place.
*/
abstract contract Pausable is Context {
/**
* @dev Emitted when the pause is triggered by `account`.
*/
event Paused(address account);
/**
* @dev Emitted when the pause is lifted by `account`.
*/
event Unpaused(address account);
bool private _paused;
/**
* @dev Initializes the contract in unpaused state.
*/
constructor() {
_paused = false;
}
/**
* @dev Modifier to make a function callable only when the contract is not paused.
*
* Requirements:
*
* - The contract must not be paused.
*/
modifier whenNotPaused() {
_requireNotPaused();
_;
}
/**
* @dev Modifier to make a function callable only when the contract is paused.
*
* Requirements:
*
* - The contract must be paused.
*/
modifier whenPaused() {
_requirePaused();
_;
}
/**
* @dev Returns true if the contract is paused, and false otherwise.
*/
function paused() public view virtual returns (bool) {
return _paused;
}
/**
* @dev Throws if the contract is paused.
*/
function _requireNotPaused() internal view virtual {
require(!paused(), "Pausable: paused");
}
/**
* @dev Throws if the contract is not paused.
*/
function _requirePaused() internal view virtual {
require(paused(), "Pausable: not paused");
}
/**
* @dev Triggers stopped state.
*
* Requirements:
*
* - The contract must not be paused.
*/
function _pause() internal virtual whenNotPaused {
_paused = true;
emit Paused(_msgSender());
}
/**
* @dev Returns to normal state.
*
* Requirements:
*
* - The contract must be paused.
*/
function _unpause() internal virtual whenPaused {
_paused = false;
emit Unpaused(_msgSender());
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)
pragma solidity ^0.8.0;
/**
* @dev Contract module that helps prevent reentrant calls to a function.
*
* Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
* available, which can be applied to functions to make sure there are no nested
* (reentrant) calls to them.
*
* Note that because there is a single `nonReentrant` guard, functions marked as
* `nonReentrant` may not call one another. This can be worked around by making
* those functions `private`, and then adding `external` `nonReentrant` entry
* points to them.
*
* TIP: If you would like to learn more about reentrancy and alternative ways
* to protect against it, check out our blog post
* https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
*/
abstract contract ReentrancyGuard {
// Booleans are more expensive than uint256 or any type that takes up a full
// word because each write operation emits an extra SLOAD to first read the
// slot's contents, replace the bits taken up by the boolean, and then write
// back. This is the compiler's defense against contract upgrades and
// pointer aliasing, and it cannot be disabled.
// The values being non-zero value makes deployment a bit more expensive,
// but in exchange the refund on every call to nonReentrant will be lower in
// amount. Since refunds are capped to a percentage of the total
// transaction's gas, it is best to keep them low in cases like this one, to
// increase the likelihood of the full refund coming into effect.
uint256 private constant _NOT_ENTERED = 1;
uint256 private constant _ENTERED = 2;
uint256 private _status;
constructor() {
_status = _NOT_ENTERED;
}
/**
* @dev Prevents a contract from calling itself, directly or indirectly.
* Calling a `nonReentrant` function from another `nonReentrant`
* function is not supported. It is possible to prevent this from happening
* by making the `nonReentrant` function external, and making it call a
* `private` function that does the actual work.
*/
modifier nonReentrant() {
_nonReentrantBefore();
_;
_nonReentrantAfter();
}
function _nonReentrantBefore() private {
// On the first call to nonReentrant, _status will be _NOT_ENTERED
require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
// Any calls to nonReentrant after this point will fail
_status = _ENTERED;
}
function _nonReentrantAfter() private {
// By storing the original value once again, a refund is triggered (see
// https://eips.ethereum.org/EIPS/eip-2200)
_status = _NOT_ENTERED;
}
/**
* @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
* `nonReentrant` function in the call stack.
*/
function _reentrancyGuardEntered() internal view returns (bool) {
return _status == _ENTERED;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)
pragma solidity ^0.8.0;
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)
pragma solidity ^0.8.0;
import "./IERC165.sol";
/**
* @dev Implementation of the {IERC165} interface.
*
* Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
* for the additional interface id that will be supported. For example:
*
* ```solidity
* function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
* return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
* }
* ```
*
* Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
*/
abstract contract ERC165 is IERC165 {
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
return interfaceId == type(IERC165).interfaceId;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC165 standard, as defined in the
* https://eips.ethereum.org/EIPS/eip-165[EIP].
*
* Implementers can declare support of contract interfaces, which can then be
* queried by others ({ERC165Checker}).
*
* For an implementation, see {ERC165}.
*/
interface IERC165 {
/**
* @dev Returns true if this contract implements the interface defined by
* `interfaceId`. See the corresponding
* https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
* to learn more about how these ids are created.
*
* This function call must use less than 30 000 gas.
*/
function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)
pragma solidity ^0.8.0;
/**
* @dev Standard math utilities missing in the Solidity language.
*/
library Math {
enum Rounding {
Down, // Toward negative infinity
Up, // Toward infinity
Zero // Toward zero
}
/**
* @dev Returns the largest of two numbers.
*/
function max(uint256 a, uint256 b) internal pure returns (uint256) {
return a > b ? a : b;
}
/**
* @dev Returns the smallest of two numbers.
*/
function min(uint256 a, uint256 b) internal pure returns (uint256) {
return a < b ? a : b;
}
/**
* @dev Returns the average of two numbers. The result is rounded towards
* zero.
*/
function average(uint256 a, uint256 b) internal pure returns (uint256) {
// (a + b) / 2 can overflow.
return (a & b) + (a ^ b) / 2;
}
/**
* @dev Returns the ceiling of the division of two numbers.
*
* This differs from standard division with `/` in that it rounds up instead
* of rounding down.
*/
function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
// (a + b - 1) / b can overflow on addition, so we distribute.
return a == 0 ? 0 : (a - 1) / b + 1;
}
/**
* @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
* @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
* with further edits by Uniswap Labs also under MIT license.
*/
function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
unchecked {
// 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
// use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
// variables such that product = prod1 * 2^256 + prod0.
uint256 prod0; // Least significant 256 bits of the product
uint256 prod1; // Most significant 256 bits of the product
assembly {
let mm := mulmod(x, y, not(0))
prod0 := mul(x, y)
prod1 := sub(sub(mm, prod0), lt(mm, prod0))
}
// Handle non-overflow cases, 256 by 256 division.
if (prod1 == 0) {
// Solidity will revert if denominator == 0, unlike the div opcode on its own.
// The surrounding unchecked block does not change this fact.
// See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
return prod0 / denominator;
}
// Make sure the result is less than 2^256. Also prevents denominator == 0.
require(denominator > prod1, "Math: mulDiv overflow");
///////////////////////////////////////////////
// 512 by 256 division.
///////////////////////////////////////////////
// Make division exact by subtracting the remainder from [prod1 prod0].
uint256 remainder;
assembly {
// Compute remainder using mulmod.
remainder := mulmod(x, y, denominator)
// Subtract 256 bit number from 512 bit number.
prod1 := sub(prod1, gt(remainder, prod0))
prod0 := sub(prod0, remainder)
}
// Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
// See https://cs.stackexchange.com/q/138556/92363.
// Does not overflow because the denominator cannot be zero at this stage in the function.
uint256 twos = denominator & (~denominator + 1);
assembly {
// Divide denominator by twos.
denominator := div(denominator, twos)
// Divide [prod1 prod0] by twos.
prod0 := div(prod0, twos)
// Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
twos := add(div(sub(0, twos), twos), 1)
}
// Shift in bits from prod1 into prod0.
prod0 |= prod1 * twos;
// Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
// that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
// four bits. That is, denominator * inv = 1 mod 2^4.
uint256 inverse = (3 * denominator) ^ 2;
// Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
// in modular arithmetic, doubling the correct bits in each step.
inverse *= 2 - denominator * inverse; // inverse mod 2^8
inverse *= 2 - denominator * inverse; // inverse mod 2^16
inverse *= 2 - denominator * inverse; // inverse mod 2^32
inverse *= 2 - denominator * inverse; // inverse mod 2^64
inverse *= 2 - denominator * inverse; // inverse mod 2^128
inverse *= 2 - denominator * inverse; // inverse mod 2^256
// Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
// This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
// less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
// is no longer required.
result = prod0 * inverse;
return result;
}
}
/**
* @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
*/
function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
uint256 result = mulDiv(x, y, denominator);
if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
result += 1;
}
return result;
}
/**
* @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
*
* Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
*/
function sqrt(uint256 a) internal pure returns (uint256) {
if (a == 0) {
return 0;
}
// For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
//
// We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
// `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
//
// This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
// → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
// → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
//
// Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
uint256 result = 1 << (log2(a) >> 1);
// At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
// since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
// every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
// into the expected uint128 result.
unchecked {
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
result = (result + a / result) >> 1;
return min(result, a / result);
}
}
/**
* @notice Calculates sqrt(a), following the selected rounding direction.
*/
function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = sqrt(a);
return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
}
}
/**
* @dev Return the log in base 2, rounded down, of a positive value.
* Returns 0 if given 0.
*/
function log2(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >> 128 > 0) {
value >>= 128;
result += 128;
}
if (value >> 64 > 0) {
value >>= 64;
result += 64;
}
if (value >> 32 > 0) {
value >>= 32;
result += 32;
}
if (value >> 16 > 0) {
value >>= 16;
result += 16;
}
if (value >> 8 > 0) {
value >>= 8;
result += 8;
}
if (value >> 4 > 0) {
value >>= 4;
result += 4;
}
if (value >> 2 > 0) {
value >>= 2;
result += 2;
}
if (value >> 1 > 0) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 2, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log2(value);
return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
}
}
/**
* @dev Return the log in base 10, rounded down, of a positive value.
* Returns 0 if given 0.
*/
function log10(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >= 10 ** 64) {
value /= 10 ** 64;
result += 64;
}
if (value >= 10 ** 32) {
value /= 10 ** 32;
result += 32;
}
if (value >= 10 ** 16) {
value /= 10 ** 16;
result += 16;
}
if (value >= 10 ** 8) {
value /= 10 ** 8;
result += 8;
}
if (value >= 10 ** 4) {
value /= 10 ** 4;
result += 4;
}
if (value >= 10 ** 2) {
value /= 10 ** 2;
result += 2;
}
if (value >= 10 ** 1) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 10, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log10(value);
return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
}
}
/**
* @dev Return the log in base 256, rounded down, of a positive value.
* Returns 0 if given 0.
*
* Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
*/
function log256(uint256 value) internal pure returns (uint256) {
uint256 result = 0;
unchecked {
if (value >> 128 > 0) {
value >>= 128;
result += 16;
}
if (value >> 64 > 0) {
value >>= 64;
result += 8;
}
if (value >> 32 > 0) {
value >>= 32;
result += 4;
}
if (value >> 16 > 0) {
value >>= 16;
result += 2;
}
if (value >> 8 > 0) {
result += 1;
}
}
return result;
}
/**
* @dev Return the log in base 256, following the selected rounding direction, of a positive value.
* Returns 0 if given 0.
*/
function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
unchecked {
uint256 result = log256(value);
return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)
pragma solidity ^0.8.0;
/**
* @dev Standard signed math utilities missing in the Solidity language.
*/
library SignedMath {
/**
* @dev Returns the largest of two signed numbers.
*/
function max(int256 a, int256 b) internal pure returns (int256) {
return a > b ? a : b;
}
/**
* @dev Returns the smallest of two signed numbers.
*/
function min(int256 a, int256 b) internal pure returns (int256) {
return a < b ? a : b;
}
/**
* @dev Returns the average of two signed numbers without overflow.
* The result is rounded towards zero.
*/
function average(int256 a, int256 b) internal pure returns (int256) {
// Formula from the book "Hacker's Delight"
int256 x = (a & b) + ((a ^ b) >> 1);
return x + (int256(uint256(x) >> 255) & (a ^ b));
}
/**
* @dev Returns the absolute unsigned value of a signed value.
*/
function abs(int256 n) internal pure returns (uint256) {
unchecked {
// must be unchecked in order to support `n = type(int256).min`
return uint256(n >= 0 ? n : -n);
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)
pragma solidity ^0.8.0;
import "./math/Math.sol";
import "./math/SignedMath.sol";
/**
* @dev String operations.
*/
library Strings {
bytes16 private constant _SYMBOLS = "0123456789abcdef";
uint8 private constant _ADDRESS_LENGTH = 20;
/**
* @dev Converts a `uint256` to its ASCII `string` decimal representation.
*/
function toString(uint256 value) internal pure returns (string memory) {
unchecked {
uint256 length = Math.log10(value) + 1;
string memory buffer = new string(length);
uint256 ptr;
/// @solidity memory-safe-assembly
assembly {
ptr := add(buffer, add(32, length))
}
while (true) {
ptr--;
/// @solidity memory-safe-assembly
assembly {
mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
}
value /= 10;
if (value == 0) break;
}
return buffer;
}
}
/**
* @dev Converts a `int256` to its ASCII `string` decimal representation.
*/
function toString(int256 value) internal pure returns (string memory) {
return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
}
/**
* @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
*/
function toHexString(uint256 value) internal pure returns (string memory) {
unchecked {
return toHexString(value, Math.log256(value) + 1);
}
}
/**
* @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
*/
function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
bytes memory buffer = new bytes(2 * length + 2);
buffer[0] = "0";
buffer[1] = "x";
for (uint256 i = 2 * length + 1; i > 1; --i) {
buffer[i] = _SYMBOLS[value & 0xf];
value >>= 4;
}
require(value == 0, "Strings: hex length insufficient");
return string(buffer);
}
/**
* @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
*/
function toHexString(address addr) internal pure returns (string memory) {
return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
}
/**
* @dev Returns true if the two strings are equal.
*/
function equal(string memory a, string memory b) internal pure returns (bool) {
return keccak256(bytes(a)) == keccak256(bytes(b));
}
}
// SPDX-License-Identifier: BUSL-1.1
pragma solidity >=0.8.19 <=0.8.20;
import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";
import {Pausable} from "@openzeppelin/contracts/security/Pausable.sol";
import {AccessControl} from "@openzeppelin/contracts/access/AccessControl.sol";
import {IController} from "../interfaces/IController.sol";
import {IBaseAdapter} from "./interfaces/IBaseAdapter.sol";
/// @title BaseAdapter
/// @notice Abstract base contract for adapters used to send and receive messages
abstract contract BaseAdapter is IBaseAdapter, Pausable, AccessControl {
/* ========== EVENTS ========== */
/// @notice Emitted when the protocol fee is set
event ProtocolFeeSet(uint48 protocolFee);
/// @notice Emitted when the minimum gas is set
event MinGasSet(uint256 minGas);
event TrustedAdapterSet(address indexed adapter, uint256 chainId);
/* ========== ERRORS ========== */
/// @notice Error when the fee transfer fails
error Adapter_FeeTransferFailed();
/// @notice Error when the provided value is less than the minimum gas limit
error Adapter_ValueIsLessThanLimit();
/// @notice Error when the address is invalid
error Adapter_InvalidAddress();
/// @notice Error when the parameters are invalid
error Adapter_InvalidParams();
/// @notice Error when the sender is unauthorised to perform an action
error Adapter_Unauthorised();
/// @notice Error when the message is invalid
error Adapter_InvalidMessage();
/// @notice Error when the Bridge message ID is already processed
error Adapter_AlreadyProcessed();
/* ========== STATE VARIABLES ========== */
/// @notice Stores received transfer IDs to prevent double processing
mapping(bytes32 => bool) internal _processedTransferIds;
/// @notice Maps chain ID to the origin forwarder address (trusted adapter on the other network)
/// @dev Only calls from these addresses are allowed when messages are received
mapping(uint256 => address) public trustedAdapters;
bytes32 public constant PAUSE_ROLE = keccak256("PAUSE_ROLE");
/// @notice Fee paid to protocol in basis points (3 decimal places)
uint48 public protocolFee;
/// @notice Decimal value for fee calculations (one percent equals 1000)
uint48 public constant FEE_DECIMALS = 1e5;
/// @notice Address where the protocol receives fees
address public protocolFeeRecipient;
/// @notice Minimum relayer fee that will be accepted
uint256 public minGas;
/// @notice Name of the adapter
string public adapterName;
/// @notice Constructor to initialize the BaseAdapter
/// @param name Name of the adapter
/// @param minimumGas Minimum gas required to relay a message
/// @param treasury Address where the protocol fees are sent
/// @param fee Fee to be charged by the protocol in basis points
constructor(string memory name, uint256 minimumGas, address treasury, uint48 fee, address owner) {
_setupRole(DEFAULT_ADMIN_ROLE, owner);
_setupRole(PAUSE_ROLE, owner);
minGas = minimumGas;
adapterName = name;
protocolFeeRecipient = treasury;
protocolFee = fee;
emit ProtocolFeeSet(fee);
emit MinGasSet(minimumGas);
}
/// @notice Checks if the given adapter is a trusted adapter for the specified chain ID
/// @param chainId The chain ID to check
/// @param adapter The adapter address to verify
/// @return True if the adapter is trusted, false otherwise
function isTrustedAdapter(uint256 chainId, address adapter) external view returns (bool) {
return trustedAdapters[chainId] == adapter;
}
/// @notice Checks if the given chain ID is supported by the adapter
/// @param chainId The chain ID to check
/// @return True if the chain ID is supported, false otherwise
function isChainIdSupported(uint256 chainId) public view returns (bool) {
return trustedAdapters[chainId] != address(0);
}
/// @notice Registers a received message and processes it
/// @dev Internal function that checks the origin sender, decodes the message, and processes it through the controller
/// @param originSender The address of the sender on the origin chain
/// @param transferId The ID of the transfer
/// @param message The message data
/// @param originChain The origin chain ID
function _registerMessage(address originSender, bytes32 transferId, bytes memory message, uint256 originChain) internal {
// Origin sender must be a trusted adapter
if (trustedAdapters[originChain] != originSender) revert Adapter_Unauthorised();
// Decode message and get the controller
BridgedMessage memory bridgedMsg = abi.decode(message, (BridgedMessage));
// If transfer id is already processed, revert
if (_processedTransferIds[transferId]) revert Adapter_AlreadyProcessed();
_processedTransferIds[transferId] = true;
IController(bridgedMsg.destController).receiveMessage(bridgedMsg.message, originChain, bridgedMsg.originController);
}
/// @notice Deducts the protocol fee from the given amount
/// @dev Internal function that checks minimum gas, calculates the fee, and transfers it to the protocol fee recipient
/// @param amount The amount from which the fee will be deducted
/// @return The amount after deducting the fee (remaining msg.value)
function _deductFee(uint256 amount) internal returns (uint256) {
if (msg.value < minGas && minGas != 0) revert Adapter_ValueIsLessThanLimit();
if (protocolFeeRecipient == address(0)) revert Adapter_FeeTransferFailed();
uint256 feeAmount = calculateFee(amount);
if (feeAmount > 0) {
// Transfer fee to protocol
(bool success, ) = protocolFeeRecipient.call{value: feeAmount}("");
if (!success) revert Adapter_FeeTransferFailed();
}
return amount - feeAmount;
}
function calculateFee(uint256 amount) public view returns (uint256) {
if (protocolFee == 0) return 0;
return Math.mulDiv(amount, protocolFee, FEE_DECIMALS);
}
/// @notice Sets the trusted adapter for a specific chain ID
/// @dev Only callable by the owner
/// @param chainId The chain ID to set the trusted adapter for
/// @param trustedAdapter The address of the trusted adapter
function setTrustedAdapter(uint256 chainId, address trustedAdapter) external onlyRole(DEFAULT_ADMIN_ROLE) {
trustedAdapters[chainId] = trustedAdapter;
emit TrustedAdapterSet(trustedAdapter, chainId);
}
/// @notice Sets the protocol fee and the recipient address
/// @dev Only callable by the owner
/// @param fee The new protocol fee in basis points
/// @param treasury The address where the protocol fees will be sent
function setProtocolFee(uint48 fee, address treasury) external onlyRole(DEFAULT_ADMIN_ROLE) {
if (fee > 5e3) revert Adapter_InvalidParams();
protocolFee = fee;
protocolFeeRecipient = treasury;
emit ProtocolFeeSet(fee);
}
/// @notice Sets the minimum gas required to relay a message
/// @dev Only callable by the owner
/// @param _minGas The new minimum gas value
function setMinGas(uint256 _minGas) external onlyRole(DEFAULT_ADMIN_ROLE) {
minGas = _minGas;
emit MinGasSet(_minGas);
}
/// @notice Pauses the contract.
/// @dev Only a user with a PAUSE_ROLE can call this function.
function pause() public onlyRole(PAUSE_ROLE) {
_pause();
}
/// @notice Unpauses the contract.
/// @dev Only a user with a PAUSE_ROLE can call this function.
function unpause() public onlyRole(PAUSE_ROLE) {
_unpause();
}
///@dev Fallback function to receive ether from bridge refunds
receive() external payable {}
}
// SPDX-License-Identifier: BUSL-1.1
pragma solidity >=0.8.19 <=0.8.20;
interface IBaseAdapter {
/// @notice Struct used by the adapter to relay messages
struct BridgedMessage {
bytes message;
address originController;
address destController;
}
/// @param destChainId The destination chain ID.
/// @param destination The destination address.
/// @param options Additional options to be used by the adapter.
/// @param message The message data to be relayed.
/// @return transferId The transfer ID of the relayed message.
function relayMessage(
uint256 destChainId,
address destination,
bytes memory options,
bytes calldata message
) external payable returns (bytes32 transferId);
/// @param chainId The chain ID to check.
/// @return bool True if the chain ID is supported, false otherwise.
function isChainIdSupported(uint256 chainId) external view returns (bool);
}
// SPDX-License-Identifier: Apache-2.0
/*
* Copyright 2024, Polymer Labs
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
pragma solidity ^0.8.0;
/**
* @title ICrossL2Prover
* @author Polymer Labs
* @notice A contract that can prove peptides state. Since peptide is an aggregator of many chains' states, this
* contract can in turn be used to prove any arbitrary events and/or storage on counterparty chains.
*/
interface ICrossL2ProverV2 {
/**
* @notice A a log at a given raw rlp encoded receipt at a given logIndex within the receipt.
* @notice the receiptRLP should first be validated by calling validateReceipt.
* @param proof: The proof of a given rlp bytes for the receipt, returned from the receipt MMPT of a block.
* @return chainId The chainID that the proof proves the log for
* @return emittingContract The address of the contract that emitted the log on the source chain
* @return topics The topics of the event. First topic is the event signature that can be calculated by
* Event.selector. The remaining elements in this array are the indexed parameters of the event.
* @return unindexedData // The abi encoded non-indexed parameters of the event.
*/
function validateEvent(
bytes calldata proof
) external view returns (uint32 chainId, address emittingContract, bytes calldata topics, bytes calldata unindexedData);
/**
* Return srcChain, Block Number, Receipt Index, and Local Index for a requested proof
*/
function inspectLogIdentifier(
bytes calldata proof
) external pure returns (uint32 srcChain, uint64 blockNumber, uint16 receiptIndex, uint8 logIndex);
/**
* Return polymer state root, height , and signature over height and root which can be verified by
* crypto.pubkey(keccak(peptideStateRoot, peptideHeight))
*/
function inspectPolymerState(bytes calldata proof) external pure returns (bytes32 stateRoot, uint64 height, bytes memory signature);
}
// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.19;
import {ReentrancyGuard} from "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import {ICrossL2ProverV2} from "./interfaces/ICrossL2ProverV2.sol";
import {BaseAdapter} from "../BaseAdapter.sol";
/// @title Polymer Adapter
/// @notice Adapter contract for cross-chain communication using the Polymer protocol.
contract PolymerAdapter is BaseAdapter, ReentrancyGuard {
/// @notice Event emitted when a chain ID has been set
event ChainIdSet(uint256 chainId, bool enabled);
/// @notice Event emitted when a message is ready to be relayed.
event RelayViaPolymer(uint256 indexed destChainId, address indexed destAdapter, bytes32 indexed transferId, bytes message);
/// @notice Error messages when quoted fee after deductions is too low
error Adapter_FeeTooLow(uint256 minGas, uint256 amount);
/// @notice Error when the proof is invalid.
error Adapter_InvalidProof();
/// @notice Event hash for the RelayViaPolymer event.
bytes32 public constant RELAY_EVENT_HASH = keccak256("RelayViaPolymer(uint256,address,bytes32,bytes)");
/// @notice Nonce used in transferId calculation, increments after each calculation.
uint256 public nonce;
/// @notice Address of the Polymer Prover contract on the same chain.
ICrossL2ProverV2 public immutable PROVER;
/// @notice Maps accesible Polymer chains IDs.
mapping(uint256 => bool) public supportedChainIds;
/// @notice Constructor to initialize the PolymerAdapter.
/// @param _prover Address of the Polymer prover contract on the same chain.
/// @param name Name of the adapter.
/// @param minimumGas Minimum gas required to relay a message. Acts as a fixed protocol fee.
/// @param treasury Address of the treasury.
/// @param chainIds Array of chain IDs supported by the adapter.
/// @param owner Owner of the adapter
constructor(
address _prover,
string memory name,
uint256 minimumGas,
address treasury,
uint256[] memory chainIds,
address owner
) BaseAdapter(name, minimumGas, treasury, 0, owner) {
if (_prover == address(0)) revert Adapter_InvalidParams();
PROVER = ICrossL2ProverV2(_prover);
for (uint256 i = 0; i < chainIds.length; i++) {
supportedChainIds[chainIds[i]] = true;
emit ChainIdSet(chainIds[i], true);
}
}
/// @notice Emits an event to be relayed to a destination chain using Polymer.
/// @dev Overloaded function that accepts a RelayedMessage struct so that the Adapter can include msg.sender.
/// @dev Refunds back to refundAddress any excess gas fees. Returned value is always 0 since no id is produced, should be ignored.
/// @param destChainId The destination chain ID.
/// @param destination The destination address.
/// @param options Additional params to be used by the adapter, abi encoded refund address.
/// @param message The message data to be relayed.
/// @return transferId Transfer ID of the relayed message.
function relayMessage(
uint256 destChainId,
address destination,
bytes memory options,
bytes memory message
) external payable override whenNotPaused nonReentrant returns (bytes32 transferId) {
// It's permissionless at this point. Msg.sender is encoded to the forwarded message
address destAdapter = trustedAdapters[destChainId];
if (!supportedChainIds[destChainId] || destAdapter == address(0)) revert Adapter_InvalidParams(); // Bridge doesn't support this chain id
bytes memory relayedMessage = abi.encode(BridgedMessage(message, msg.sender, destination));
_collectAndRefundFees(abi.decode(options, (address)));
transferId = calculateTransferId(destChainId);
// Increment nonce used to create transfer id
nonce++;
// emit event
emit RelayViaPolymer(destChainId, destAdapter, transferId, relayedMessage);
}
/// @notice Receives a message.
/// @param proof A hex encoded proof from Polymer.
function receiveMessage(bytes calldata proof) external virtual whenNotPaused {
(uint32 originChainId, address sourceAdapter, bytes memory topics, bytes memory unindexedData) = PROVER.validateEvent(proof);
// If proof is invalid, PROVER.validateEvent() reverts
address originAdapter = trustedAdapters[originChainId];
// Decode and verify indexed topics (dest chain id and dest adapter are the same)
(bytes32 eventHash, uint256 destChainId, address destAdapter, bytes32 transferId) = abi.decode(topics, (bytes32, uint256, address, bytes32));
if (((destAdapter != address(this)) || (destChainId != block.chainid)) || (originAdapter == address(0)) || (eventHash != RELAY_EVENT_HASH))
revert Adapter_InvalidProof();
_registerMessage(sourceAdapter, transferId, abi.decode(unindexedData, (bytes)), originChainId);
}
/**
* @notice Calculates the transfer ID based on the provided parameters.
* @param destChainId The destination chain ID.
* @return The calculated transfer ID.
*/
function calculateTransferId(uint256 destChainId) public view returns (bytes32) {
return keccak256(abi.encode(destChainId, block.chainid, nonce));
}
/// @dev Internal function to collect fees and refund the difference if necessary
/// @param refundAddress The user address to receive a refund
function _collectAndRefundFees(address refundAddress) internal {
uint256 remainingValue = _deductMinGas(msg.value);
if (remainingValue != 0) {
// refund excess
(bool success, ) = refundAddress.call{value: remainingValue}("");
if (!success) revert Adapter_FeeTransferFailed();
}
}
/// @notice Deducts the protocol fee from the given amount
/// @dev Internal function that collects the minimumGas and transfers it to the protocol fee recipient
/// @param amount The amount from which the fee will be deducted
/// @return The amount after deducting the fee (remaining value)
function _deductMinGas(uint256 amount) internal returns (uint256) {
if (amount < minGas && minGas != 0) revert Adapter_FeeTooLow(minGas, amount);
if (minGas > 0) {
if (protocolFeeRecipient == address(0)) revert Adapter_FeeTransferFailed();
// Transfer fee to protocol
(bool success, ) = protocolFeeRecipient.call{value: minGas}("");
if (!success) revert Adapter_FeeTransferFailed();
}
return amount - minGas;
}
/// @notice Sets domain IDs and corresponding chain IDs.
/// @dev Only the owner can call this function.
/// @param chainIds Array of chain IDs.
/// @param enabled Boolean array to enable or disable the chain IDs.
function setDomainId(uint256[] memory chainIds, bool enabled) external onlyRole(DEFAULT_ADMIN_ROLE) {
for (uint256 i = 0; i < chainIds.length; i++) {
supportedChainIds[chainIds[i]] = enabled;
emit ChainIdSet(chainIds[i], enabled);
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity >=0.8.19 <=0.8.20;
interface IController {
/**
* @notice Registers a received message.
* @param message The received message data in bytes.
* @param originChain The origin chain ID.
* @param originSender The address of the origin sender. (controller in origin chain)
*/
function receiveMessage(bytes calldata message, uint256 originChain, address originSender) external;
/**
* @notice Returns the controller address for a given chain ID.
* @param chainId The chain ID.
* @return The controller address.
*/
function getControllerForChain(uint256 chainId) external view returns (address);
}